经常有程序需要交叉编译，手工写Makefile写的太混乱了，学习用Autotools来生成Makefile方便许多。
下面记录了一个mp3播放器简单程序使用Autotools的步骤。
播放器支持使用OSS接口，也支持使用ALSA接口来输出声音。
1.进入工程目录，执行autoscan，在此目录下生成了configure.scan文件。修改此文件内容，并重新命名为configure.ac。最终的内容如下：
AC_PREREQ([2.63])
# !!!修改模块名，版本号，bug report为自己所需要的内容。
AC_INIT([mp3player], [1.0], [root@localhost])
# !!!手工添加此句。以使用Automake。
AM_INIT_AUTOMAKE(mp3player,1.0)
# 一个有效的代码文件。可手工改动，亦可保持不变。
AC_CONFIG_SRCDIR([src/main.c])
# 指定Autoheader生成的头文件名。一般保持config.h不变。
AC_CONFIG_HEADERS([config.h])
# Checks for programs.
# 检测c编译器。如果代码中有c代码scan时会自动添加
AC_PROG_CC
# 检测c++编译器。如果代码中有c++代码scan时会自动添加。本项目不用，就注释掉了。
# AC_PROG_CXX
# Checks for libraries.
# 检测pthread库是否存在
#
# AC_CHECK_LIB(库名称,需要库中的函数,[如果找到,[如果没找到]])
AC_CHECK_LIB(pthread, pthread_create, HAVE_PTHREAD=yes,HAVE_PTHREAD=no)
if test "$HAVE_PTHREAD" = "no"; then
# 输出错误信息。configure会终止。
AC_MSG_ERROR([pthread is required])
fi
# 定义PTHREAD的LDFLAG，以在Makefile.am中加入到链接器参数中去。
PTHREAD_LIBS=-lpthread
# AC_SUBST 定义的变量可以在Makefile.am中使用
AC_SUBST(PTHREAD_LIBS)
# Check use OSS or ALSA
# 此宏定义的模块，可以在configure时通过--with-oss启用。
AC_ARG_WITH([oss], [AS_HELP_STRING([--with-oss],[Use OSS sound api instead of ALSA])], [USE_ALSA=no], [USE_ALSA=yes])
if test "$USE_ALSA" = "no"; then
# 输出一些提示信息
AC_MSG_NOTICE(Use OSS api.)
# 在config.h中添加一个宏。程序中可以使用#ifdef来检测。
AC_DEFINE(USE_OSS,,[Use OSS api if this macro is defined.])
else
#检测ALSA库是不是存在。
#最小版本号。
ASOUND_VER=0.9
# PKG_CHECK_MODULES(VARIABLE-PREFIX, MODULES, [action-if-found], [action-if-not-fount])
# 前缀是用来定义变量的，MODULES是一个表达式，这儿要注意的是，虽然Alsa库是libasound，但是其pkg-config配置文件是alsa.pc，所以这儿是检测alsa而不是ASOUND >= $ASOUND_VER。
PKG_CHECK_MODULES(ASOUND, alsa >= $ASOUND_VER, HAVE_ASOUND=yes,HAVE_ASOUND=no)
if test "$HAVE_ASOUND" = "no"; then
AC_MSG_ERROR([alsa >= $ASOUND_VER is required])
fi
# 到这儿时已经自动生成了Alsa库的CFLAGS，LIBS，用到了前缀。将这两个宏公布出去，以在Makefile.am中使用。
AC_SUBST(ASOUND_LIBS)
AC_SUBST(ASOUND_CFLAGS)
fi
# Checks for header files.
AC_CHECK_HEADERS([fcntl.h stdlib.h sys/ioctl.h unistd.h])
# Checks for typedefs, structures, and compiler characteristics.
AC_HEADER_STDBOOL
AC_C_INLINE
# Checks for library functions.
AC_FUNC_MALLOC
AC_CHECK_FUNCS([clock_gettime strncasecmp])
# !!!这句要有
AC_CONFIG_FILES([Makefile])
AC_OUTPUT
2.运行aclocal处理本地宏定义
3.autoconf生成configure文件
4.autoheader生成config.h.in文件
5.创建Makefile.am文件，automake会根据此文件生成Makefile.in文件，最终configure根据Makefile.in生成最后的Makefile。最终的Makefile.am文件内容如下：
# 可执行文件名。后面的变量都会以这个为前缀。
bin_PROGRAMS= mp3player
# 所有的代码文件
mp3player_SOURCES= src/main.c src/decoder.c src/device.c src/mp3file.c src/outputter.c src/pcmBuffer.c src/player.c src/playthread.c
# 需要额外链接的静态库
mp3player_LDADD=./mad/lib/libmad.a
# 需要额外链接的动态库。这儿用到的PTHREAD_LIBS，ASOUND_LIBS都是在configure.ac中公布出来的。
mp3player_LDFLAGS=$(PTHREAD_LIBS) -lrt $(ASOUND_LIBS)
# 需要额外添加的编译器参数。
mp3player_CFLAGS=-I./mad/include $(ASOUND_CFLAGS)
# 此选项告诉automake不要检测此目录下是否有README,NEWS,AUTHORS,ChangeLog这些文件了
AUTOMAKE_OPTIONS=foreign
6.automake --add-missing --copy
根据Makefile.am 生成Makefile.in文件
7.运行configure,根据Makefile.in生成实际的Makefile。如果不带任何参数，可以看到输出有检测alsa的提示。如果./configure --with-oss就可以看到提示使用OSS接口。并且打开config.h，可以找到#define USE_OSS这个我们在configure.ac中指定的宏。
8.为了方便添加原文件后，不再重复以上步骤，写一个autogen.sh脚本，内容如下：
aclocal
autoheader
automake --add-missing --copy
autoconf
以后无论是修改configure.ac增加库的引用还是修改Makefile.am增加源文件，只要重新执行一遍这个脚本就可以了。